SetLocal EnableExtensions EnableDelayedExpansion

Echo ઠ 䠩 ADDONS.HTM

Set Autor=IDDQDesnik
Set Include=%~1\IncHtml
Set Addons=%~dp0AllFolders.txt
Set Thanks=%~dp0thanks
Set OS=%~dp0ADDONS.HTM
Set IsEmpty=1
Set UpdName=

::   UpdatePack'a
Expand Files\ForceCopy\RUSUPPCK.IN_ Temp\RusUpPck.inf >nul
For /F "UseBackQ Tokens=1* Delims==" %%K In ("Temp\RusUpPck.inf") Do (
  If /I "%%K"=="OptionDesc	" Set UPDName=%%~L
)
Set UPDName=%UPDName:~2,-1%

::   Thanks     
If Exist "!Include!\Thanks" (
  Type "!Include!\Thanks" >"!Thanks!"
) Else (
  If Exist "!Thanks!" Del /f /q "!Thanks!" >nul
)

::    
Set AddonTitle=Microsoft^&reg; Windows^&reg; XP Professional SP2 with the %UPDName%

SetLocal DisableDelayedExpansion
Echo ^<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN"^> >"%OS%"
EndLocal

Echo ^<HTML^> >>"%OS%"
Call :TypeHead "!Include!\Addons.css"
Echo ^<BODY^> >>"%OS%"

If Exist "!Include!\LogoImage" Type "!Include!\LogoImage" >>"%OS%"

::  Introduction
Set UseBanner=1
Set AddonBuild=%Date%
Set AddonAuthor=%Autor%
Set AddonHtRef=
Echo.  ^<DIV class="block"^> >>"%OS%"
Set AddonTitle=Microsoft^&reg; Windows^&reg; XP Professional SP2 with the %UPDName%
Call :TypeTitle H1
Echo.  ^</DIV^> >>"%OS%"
If Exist !Include!\Introduction Type "!Include!\Introduction" >>"%OS%"
Set UseBanner=0
Set AddonTitle=
Set AddonBuild=

::  
Echo.  ^<DIV class="toc"^> >>"%OS%"
Echo.    ^<A name="toc"^>^</A^> >>"%OS%"
Echo.    ^<H1^>^</H1^> >>"%OS%"
Echo.    ^<HR^> >>"%OS%"
Set Level="toc1"
Call :TypeTocItem "" !Level! ""
For /F "usebackq Delims=" %%I In ("!Addons!") Do (
  If Exist "%%~I\Html.nfo" (
    Call :TypeTocItem "%%~I\Html.nfo" !Level! "%%I"
  ) Else (
    If Exist "%%~I\Addon.nfo" (
      Call :TypeTocItem "%%~I\Addon.nfo" !Level! "%%I"
    ) Else (
      If "%%I"=="." (
        Set AddonTitle= 
        Call :TypeTocItem "" !Level! " "
      )
    )
  )
  Set Level="toc2"
)
Call :TypeTocItem "!Thanks!" "toc1" ""
Echo.  ^</DIV^> >>"%OS%"
If Exist !Include!\OemInfo Type "!Include!\Toc" >>"%OS%"

::  OEM Information
Set UseBanner=0
Set AddonTitle=
Call :TypeTitle H1 ""
If Exist !Include!\OemInfo Type "!Include!\OemInfo" >>"%OS%"
Set AddonTitle=
Echo.  ^<BR^>^<A class="finePrint" href="#toc"^>^</A^>^<BR^> >>"%OS%"

::  Addons
Set UseBanner=0
Set AddonTitle= 
Call :TypeTitle H1 " "
If Exist !Include!\Addons Type !Include!\Addons  >>"%OS%"
Set AddonTitle=
Set ErrFlag=1
Set Level="H1"
For /F "usebackq Delims=" %%I In ("!Addons!") Do (
  If Exist "%%~I\Html.nfo" (
    Call :TypeBlock "%%~I\Html.nfo" !Level! "%%I"
  ) Else (
    Call :TypeBlock "%%~I\Addon.nfo" !Level! "%%I"
  )
  Call :SaveCopyright "!Thanks!" !Level!
  Set Level="H2"
)
Set IsEmpty=%ErrFlag%

::  Thanks 
Set UseBanner=0
Set AddonTitle=
Call :TypeTitle H1 
Echo.  ^</DIV^> >>"%OS%"
Set AddonTitle=
Echo ^<P^> >>"%OS%"
Echo ^&copy;^&nbsp;^<strong^>Petya V4sechkin ^</strong^> ^&#8212; >>"%OS%"
Echo ^<A href="http://unattended.fatal.ru"^>%UPDName:~0,20%^</A^> >>"%OS%"
Echo : %UPDName:~-7% >>"%OS%"
Echo ^</P^ >>"%OS%" 
Type "!Thanks!" >>"%OS%"
Echo.  ^<BR^>^<A class="finePrint" href="#toc"^>^</A^>^<BR^> >>"%OS%"
Echo.  ^<P^>^&nbsp;^</P^> >>"%OS%"
Echo ^</BODY^> >>"%OS%"
Echo ^</HTML^> >>"%OS%"

If "%IsEmpty%"=="1" (
  Echo  ADDONS.HTM   ᠭ 
) Else (
  Type "%OS%" >"%Distr%\ADDONS.HTM"
)
GoTo :EOF

::GetParam "file"
:GetParam
  Set UsePRE=1
  Set ForcePRE=
  Set UseBanner=
  Set AddonHide=
  Set AddonTitle=
  Set AddonAuthor=
  Set AddonBuild=
  Set AddonHtRef=
  If Not Exist "%~1" (
    Set AddonHide=1
    GoTo :EOF
  )
  For /F "usebackq Tokens=1,* Delims== " %%I In ("%~dpnx1") Do (
    ::   
    If /I "%%I"=="ADDON_TITLE" (
      Set AddonTitle=%%~J
      Set UsePRE=%ForcePRE%
    )
    If /I "%%I"=="ADDON_AUTHOR" (
      Set AddonAuthor=%%~J
      Set UsePRE=%ForcePRE%
      Set UseBanner=1
    )
    If /I "%%I"=="ADDON_BUILD" (
      Set AddonBuild=%%~J
      Set UsePRE=%ForcePRE%
      Set UseBanner=1
    )
    If /I "%%I"=="ADDON_URL" (
      Set AddonHtRef=%%~J
      Set UsePRE=%ForcePRE%
      Set UseBanner=1
    )
    If /I "%%I"=="NO_HYPERTEXT" (
      Set ForcePRE=%%~J
      Set UsePRE=%%~J
    )
    If /I "%%I"=="ADDON_HIDE" (
      Set AddonHide=%%~J
    )
    ::  (  )
    If "%%I"=="-->" GoTo :EOF
  )
GoTo :EOF

:: TypeHead "file.css"
:TypeHead
  Set UsePRE=
  Echo ^<HEAD^> >>"%OS%"
  Echo.  ^<title^>!AddonTitle!^</title^> >>"%OS%"
  Echo.  ^<meta http-equiv="Content-Type" content="text/html; charset=windows-1251"^> >>"%OS%"
  Echo.  ^<meta content="(c) asmol, 2007, addon HTMLINFO, http://forum.oszone.net/thread-90061.html" name=GENERATOR^> >>"%OS%"
  Call :TypeFile "%~1"
  Echo ^</HEAD^> >>"%OS%"
GoTo :EOF

:: TypeTitle "H1" "ancor"
:TypeTitle
  If Not "%~2"=="" (
    Echo.  ^<A name="%~nx2"^>^</A^> >>"%OS%"
  )
  Echo.  ^<TABLE class="heading" cellPadding=0 cellSpacing=0 width="100%%"^> >>"%OS%"
  Echo.    ^<TR vAlign=bottom^> >>"%OS%"
  Echo.      ^<TD width="100%%"^>^<%~1^>!AddonTitle!^</%~1^>^</TD^> >>"%OS%"
  If "!UseBanner!"=="1" (
    Echo.  ^<TD^>^<DIV class="banner"^> >>"%OS%"
    If Not "!AddonAuthor!"=="" (
      Echo.    ^<P^>: ^<strong^>!AddonAuthor!^</strong^>^</P^> >>"%OS%"
    )
    If Not "!AddonBuild!"=="" (
      If "!AddonBuild!"=="Date" Set AddonBuild=%Date%
      Echo.    ^<P^>: ^<strong^>!AddonBuild!^</strong^>^</P^> >>"%OS%"
    )
    If Not "!AddonHtRef!"=="" (
      Echo.    ^<P^>^<A href="!AddonHtRef!" target="_blank"^> ^</A^>^</P^> >>"%OS%"
    )
    Echo.  ^</DIV^>^</TD^> >>"%OS%"
  )
  Echo.    ^</TR^> >>"%OS%"
  Echo.  ^</TABLE^> >>"%OS%"
  Echo.  ^<HR^> >>"%OS%"
GoTo :EOF

:: TypeFile "file"
:TypeFile
  If Not Exist "%~1" GoTo :EOF
  If "!UsePRE!"=="1" Echo ^<PRE^> >>"%OS%"
  Type "%~1" >>"%OS%"
  If "!UsePRE!"=="1" Echo ^</PRE^> >>"%OS%"
GoTo :EOF

:: TypeTocItem "file" "toc1" "link"
:TypeTocItem
  If Not "%~1"=="" (
    Call :GetParam "%~1"
    If "!AddonHide!"=="1" GoTo :EOF
  )
  If "!AddonTitle!"=="" Set AddonTitle=%~nx3
  If "!AddonTitle!"=="" Set AddonTitle=%~nx1
  If Not "%~3"=="" (
    Echo.    ^<P class="%~2"^>^<A href="#%~nx3"^>!AddonTitle!^</A^>^</P^> >>"%OS%"
  ) Else (
    Echo.    ^<P class="%~2"^>!AddonTitle!^</P^> >>"%OS%"
  )
GoTo :EOF

:: TypeBlock "file" "H1" "link"
:TypeBlock
  Call :GetParam "%~1"
  Set SaveAddonTitle=!AddonTitle!
  If "!AddonHide!"=="1" GoTo :EOF
  If "!AddonTitle!"=="" Set AddonTitle=%~nx3
  If "!AddonTitle!"=="" Set AddonTitle=%~nx1
  Echo.  ^<DIV class="block"^> >>"%OS%"
  Call :TypeTitle "%~2" "%~nx3"
  Call :TypeFile "%~1"
  Echo.  ^</DIV^> >>"%OS%"
  If Not "%~nx3"=="" (
    Echo.      ^<BR^>^<A class="finePrint" href="#toc"^>^</A^>^<BR^> >>"%OS%"
  )
  Set AddonTitle=!SaveAddonTitle!
  Set SaveAddonTitle=
  Set ErrFlag=
GoTo :EOF

:: SaveCopyright "file" "H1"
:SaveCopyright
  If "!AddonHide!"=="1" GoTo :EOF
  If "!AddonAuthor!"=="" GoTo :EOF
  If "!AddonTitle!"=="" GoTo :EOF
  Echo ^<P^> >>%1
  If "%~2"=="H1" (
    Echo ^&copy;^&nbsp;^<strong^>!AddonAuthor!^</strong^> ^&#8212; >>%1
  ) Else (
    Echo ^&copy;^&nbsp;^<strong^>!AddonAuthor!^</strong^> ^&#8212; ^&nbsp; >>%1
  )
  If Not "!AddonHtRef!"=="" (
    Echo ^<A href="!AddonHtRef!"^>!AddonTitle!^</A^> >>%1
  ) Else (
    Echo !AddonTitle! >>%1
  )
  If Not "!AddonBuild!"=="" Echo  !AddonBuild! >>%1
  Echo ^</P^> >>%1
GoTo :EOF
