[kaster]

klsorat2010, это не ссылка а раскрывающийся блок текста в котором код. вот такой

Код:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>

_IEErrorHandlerRegister()

$oIE = _IECreateEmbedded()
$hForm = GUICreate("Супер-пупер программа", 640, 580, _
        (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, _
        $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
$GUIActiveX = GUICtrlCreateObj($oIE, 5, 5, 630, 520)
$GUI_Button_Test = GUICtrlCreateButton("Пройти тест", 55, 530, 150, 30)
$GUI_Button_Check = GUICtrlCreateButton("Проверить результат", 245, 530, 150, 30)
GUICtrlSetState(-1, $GUI_DISABLE)
$GUI_Button_Home = GUICtrlCreateButton("Домой", 435, 530, 150, 30)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState()

_IENavigate($oIE, "http://www.mail.ru/")

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
        Case $msg = $GUI_Button_Test
            _IENavigate($oIE, "http://forum.oszone.net/")
            GUICtrlSetState($GUI_Button_Check, $GUI_ENABLE)
        Case $msg = $GUI_Button_Check
            GUICtrlSetState($GUI_Button_Check, $GUI_DISABLE)
            GUICtrlSetState($GUI_Button_Test, $GUI_DISABLE)
            $sText = _IEBodyReadText($oIE)
            If StringInStr($sText, "Забыли пароль") <> 0 Then
                MsgBox(266256, "Ошибка!", "Вы или не зарегистрированы, или забыли войти")
            Else
                If MsgBox(266308, "Успех!", "Вы успешно вошли в форум!" & @CRLF & @CRLF & _
                        "Открыть блокнот?") = 6 Then Run("notepad")
            EndIf
            GUICtrlSetState($GUI_Button_Home, $GUI_ENABLE)
        Case $msg = $GUI_Button_Home
            GUICtrlSetState($GUI_Button_Home, $GUI_DISABLE)
            _IENavigate($oIE, "http://www.mail.ru/")
            GUICtrlSetState($GUI_Button_Test, $GUI_ENABLE)
    EndSelect
WEnd

[gregaz]

И что это? Ссылк аведет на эту же страницу »

там просто раскрывающийся блок с кодом того, что тебе надо

[Iska]

И что это? Ссылка ведет на эту же страницу »

Разрешите в Вашем браузере исполнение скриптов для домена «forum.oszone.net» (а лучше сразу для «oszone.net»).

[klsorat2010]

спасибо конечно, тока я не вижу где же сам поиск слова то?

[madmasles]

klsorat2010,

Код:

$sText = _IEBodyReadText($oIE)

Читаем с окна IE тот текст, который сами видим на экране.

Код:

If StringInStr($sText, "Забыли пароль") <> 0 Then
                MsgBox(266256, "Ошибка!", "Вы или не зарегистрированы, или забыли войти")
            Else
                If MsgBox(266308, "Успех!", "Вы успешно вошли в форум!" & @CRLF & @CRLF & _
                        "Открыть блокнот?") = 6 Then Run("notepad")
            EndIf

Если находим на экране текст "Забыли пароль", то "Ошибка!", если не находим, то "Успех!" и вопрос - "Открыть блокнот?". Если "Да", то открываем блокнот.
Вы попробуйте выйти из учетной записи и проверить скрипт, потом войти на форум и опять проверить скрипт.

[klsorat2010]

madmasles спасибо, тока как мне это в html то впихнуть?

да и блокнот не запускается если выйти/войти на этоот форум

[madmasles]

klsorat2010,
А зачем его запихивать в html? Он и так работает (у меня). Попробуйте вставить свои ссылки, свое слово для поиска, свою программу для запуска.
У меня на Win XP блокнот открывает, попробуйте в самой первой строке написать #RequireAdmin, если у Вас Vista или 7.

У меня работает с вашими файлами (я их переименовал на расширение .html) и с такой ссылкой: file://localhost/C:/исходный%20код.html, и с такой: C:\htafile_.hta.html.

[klsorat2010]

чет я не пойму, а какое тогда расширение ставить если не html?

[madmasles]

klsorat2010,
Вы имеете в виду расширение самого скрипта? Его расширение должно быть .au3

[klsorat2010]

#RequireAdmin
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>

перед "#RequireAdmin " #include не надо?

и как его тогда запускать если он .au3?